***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Oct 18, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt BZX84C3V6-AU A K 
.param
+vc0 = 1.046e-13	vc1 = 6.016e-10		vc2 = 1.000		vc3 = 7.536e-8		vc4 = 8.591
+tc1 = 2.451e-2		tc2 = 1.121e-2		tc3 = 3.101e-3		tc4 = 1.021e-3
.func irpwr(v) {(vc0+vc1*v**vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*v**vc4)*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irpwr(v(K,A))}
.model zener d
***** flag parameter *****
+level = 1 
***** dc model parameter *****
+ is = 4.042e-15	   n = 1.076		  rs = 4.506e-1
+ibv = 1e-3		 nbv = 5.0		  bv = 3.6
+ikf = 1.300e-1
***** capacitance parameter *****
+cjo = 1.711e-10	   m = 3.586e-1		  vj = 7.780e-1 
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.125		 xti = 3
+trs1 = 9.885e-4	trs2 = 5.605e-6		tikf = 3e-3
+tbv1 = -8.638e-4	tbv2 = 2.061e-7	
.ends BZX84C3V6-AU
*$
